RFC 3508 (rfc3508) - Page 2 of 6
H
Alternative Format: Original Text Document
RFC 3508 H.323 URL Scheme April 2003
1. Introduction
ITU-T Recommendations H.323 [3] and H.225.0 [4] define a system for
multimedia communications services over packet based networks.
H.225.0 [4] defines an alias type for carrying any standard Uniform
Resource Locator (URL). H.323 version 4 [3] introduced an H.323-
specific URL, which may be used to resolve the address of a network
entity to which H.323 calls may be directed.
This document reproduces the H323-URL definition found in ITU-T
recommendation H.323 [3] and is published as an RFC for ease of
access and IANA registration.
2. URL Scheme Formal Syntax Definition and Character Encoding
The H.323 URL is defined in ABNF as shown below. Note that it
utilizes the Core Rules specified in section 6.1 of [2].
H323-URL = "h323:" address [ url-parameters ]
address = user / "@" hostport / user "@" hostport
user = 1*(%x21-24 / %x26-3F / %x41-7F / escaped)
; The symbols "%", "@", and symbols with
; a character value below 0x21 may be
; represented as escaped sequences.
hostport = host [ ":" port]
host = hostname / IPv4address / IPv6reference
hostname = *( domainlabel "." ) toplabel [ "." ]
domainlabel = alphanum / alphanum *( alphanum / "-" ) alphanum
toplabel = ALPHA / ALPHA *( alphanum / "-" ) alphanum
IPv4address = 1*3DIGIT "." 1*3DIGIT "." 1*3DIGIT "." 1*3DIGIT
IPv6reference = "[" IPv6address "]"
IPV6address = hexpart [ ":" IPv4address ]
hexpart = hexseq / hexseq "::" [ hexseq ] / "::" [ hexseq ]
hexseq = hex4 *( ":" hex4 )
hex4 = 1*4HEXDIG
port = 1*DIGIT
url-parameters = *( ";" url-parameter )
url-parameter = 1*(%x21-24 / %x26-3A / %x3C-7F / escaped)
; Specific parameter definitions are for
; further study.
; The symbols "%", ";", and symbols
; with a character value below 0x21 may be
; represented as escaped sequences.
alphanum = ALPHA / DIGIT
escaped = "%" HEXDIG HEXDIG
The host is case insensitive.
Levin Informational